Improved hex editing

The help files for vim include the following advice for automating the xxd-style hex editing capabilities for vim:

 " vim -b : edit binary using xxd-format!
 augroup Binary
   au!
   au BufReadPre  *.bin let &bin=1
   au BufReadPost *.bin if &bin | %!xxd
   au BufReadPost *.bin set ft=xxd | endif
   au BufWritePre *.bin if &bin | %!xxd -r
   au BufWritePre *.bin endif
   au BufWritePost *.bin if &bin | %!xxd
   au BufWritePost *.bin set nomod | endif
 augroup END

There are a few problems with this approach: 1) Only files with a .bin extension are opened this way, even if editing a file in binary mode (e.g. with ++bin) 2) This sets the binary option for any future documents opened as well. If you use tabe, for example, or if you have Vim set up to open new files in tabs using --remote-tab-silent, then any new files opened will open in binary mode. 3) If you decide to edit a binary file without the xxd, the BufWrite autocommands will try to convert it with xxd -r anyway.

I've been able to fix all these problems as follows:

Put the following in your vimrc file:

 if has("autocmd")
   " vim -b : edit binary using xxd-format!
   augroup Binary
     au!
     au BufReadPre *.bin,*.hex setlocal binary
     au BufReadPost * 
           \ if &binary | exe "Hexmode" | endif
     au BufWritePre *
           \ if exists("b:editHex") && b:editHex && &binary |
           \  exe "%!xxd -r" |
           \ endif
     au BufWritePost *
           \ if exists("b:editHex") && b:editHex && &binary |
           \  exe "%!xxd" |
           \  exe "set nomod" |
           \ endif
   augroup END
 endif

 command Hexmode call ToggleHex()
 
 function ToggleHex()
   " hex mode should be considered a read-only operation
   " save values for modified and read-only for restoration later,
   " and clear the read-only flag for now
   let l:modified=&mod
   let l:oldreadonly=&readonly
   let &readonly=0
   if !exists("b:editHex") || !b:editHex
     " save old options
     let b:oldft=&ft
     let b:oldbin=&bin
     " set new options
     setlocal binary " make sure it overrides any textwidth, etc.
     let &ft="xxd"
     " set status
     let b:editHex=1
     " switch to hex editor
     %!xxd
   else
     " restore old options
     let &ft=b:oldft
     if !b:oldbin
       setlocal nobinary
     endif
     " set status
     let b:editHex=0 
     " return to normal editing
     %!xxd -r
   endif
   " restore values for modified and read only state
   let &mod=l:modified
   let &readonly=l:oldreadonly
 endfunction

This will make vim automatically use xxd-format hex editing when the file is opened in binary mode, and will automatically (locally) set binary mode for .bin and .hex files! In addition, it provides a command "Hexmode" for entering the xxd format properly.

In addition, I use the sendto menu in Windows XP for editing files in tabs with gVim. Here's some handy shortcuts to add for sending stuff to the hex editor set up above: 1) Launch in tabs in a new dedicated vim hex editor: "C:\Program Files\Vim\vim71\gvim.exe" -p -b -c "set binary" --servername HEXVIM 2) Launch in tabs in an existing dedicated vim hex editor: "C:\Program Files\Vim\vim71\gvim.exe" -b -c "set binary" --servername HEXVIM --remote-tab-silent