Wikia

Vim Tips Wiki

Search for visually selected text

Talk0
1,612pages on
this wiki
Tip 171 Printable Monobook Previous Next

created 2001 · complexity basic · author Raymond Li · version 6.0


With this tip, you can select some text, then press a key to search for the next occurrence of the text. Two alternative methods are presented.

Simple Edit

The simplest solution is:

vnorem // y/<c-r>"<cr>

Advanced Edit

The following is a more advanced implementation, with more robust functionality than the above keymap.

Features

  • Press * to search forwards for selected text, or # to search backwards.
  • As normal, press n for next search, or N for previous.
  • Handles multiline selection and search.
  • Whitespace in the selection matches any whitespace when searching (searching for "hello world" will also find "hello" at the end of a line, with "world" at the start of the next line).
  • Each search is placed in the search history allowing you to easily repeat previous searches.
  • No registers are changed.

Place the following mappings in your vimrc:

" Search for selected text, forwards or backwards.
vnoremap <silent> * :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy/<C-R><C-R>=substitute(
  \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>
vnoremap <silent> # :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy?<C-R><C-R>=substitute(
  \escape(@", '?\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>

Following is an alternative version with some extra features:

  • A global variable (g:VeryLiteral) controls whether selected whitespace matches any whitespace (by default, VeryLiteral is off, so any whitespace is found).
  • Type \vl to toggle VeryLiteral to turn whitespace matching off/on (assuming the default backslash leader key).
  • When VeryLiteral is off, any selected leading or trailing whitespace will not match newlines, which is more convenient, and avoids false search hits.

Create file (for example) ~/.vim/plugin/vsearch.vim (Unix) or $HOME/vimfiles/plugin/vsearch.vim (Windows) with contents:

" Search for selected text.
" http://vim.wikia.com/wiki/VimTip171
let s:save_cpo = &cpo | set cpo&vim
if !exists('g:VeryLiteral')
  let g:VeryLiteral = 0
endif
function! s:VSetSearch(cmd)
  let old_reg = getreg('"')
  let old_regtype = getregtype('"')
  normal! gvy
  if @@ =~? '^[0-9a-z,_]*$' || @@ =~? '^[0-9a-z ,_]*$' && g:VeryLiteral
    let @/ = @@
  else
    let pat = escape(@@, a:cmd.'\')
    if g:VeryLiteral
      let pat = substitute(pat, '\n', '\\n', 'g')
    else
      let pat = substitute(pat, '^\_s\+', '\\s\\+', '')
      let pat = substitute(pat, '\_s\+$', '\\s\\*', '')
      let pat = substitute(pat, '\_s\+', '\\_s\\+', 'g')
    endif
    let @/ = '\V'.pat
  endif
  normal! gV
  call setreg('"', old_reg, old_regtype)
endfunction
vnoremap <silent> * :<C-U>call <SID>VSetSearch('/')<CR>/<C-R>/<CR>
vnoremap <silent> # :<C-U>call <SID>VSetSearch('?')<CR>?<C-R>/<CR>
vmap <kMultiply> *
nmap <silent> <Plug>VLToggle :let g:VeryLiteral = !g:VeryLiteral
  \\| echo "VeryLiteral " . (g:VeryLiteral ? "On" : "Off")<CR>
if !hasmapto("<Plug>VLToggle")
  nmap <unique> <Leader>vl <Plug>VLToggle
endif
let &cpo = s:save_cpo | unlet s:save_cpo

ExplanationEdit

The first suggested mapping was:

vnoremap <silent> * :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy/<C-R><C-R>=substitute(
  \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>

When in visual mode, pressing * will then perform these commands:

:<C-U>
let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
gvy
/<C-R><C-R>=
substitute(
  escape(@", '/\.*$^~['),
  '\_s\+',
  '\\_s\\+',
  'g')<CR><CR>
gV
:call setreg('"', old_reg, old_regtype)<CR>

:<C-U> enters command mode and deletes (Ctrl-u) the '<,'> range automatically inserted due to the visual selection. The unnamed register (@") is saved and later restored.

gvy reselects then yanks the visual selection (copy to @").

/<C-R><C-R>= starts a search, then substitutes the expression register (@=) literally :help c_CTRL-R_CTRL-R. The result of the following expression is inserted into the command line.

escape() inserts a backslash before each /\.*$^~[ character found in @". The / must be escaped because we are using a / command. The other characters need to be escaped because they have a special meaning in a regular expression.

substitute() replaces every sequence of one or more whitespace characters (space, tab, newline) with an escaped regular expression that will search for any similar sequence.

gV allows the mappings to work in --SELECT-- mode as well as --VISUAL--. Without gV, searching for text in select mode would not move the cursor because the selection is automatically reselected after the mapping.


Paste matching text of last searchEdit

When using ^r/ in INSERT mode what one most of the time wants is to paste the matched text not the regex used to search the text. Example: after using * on a word, ^r/ will paste the word with \< prepended and \> appended, not what we want. Similarly after a visual search we don't want the \V prepended. The following map takes care of these issues:

function! Del_word_delims()
   let reg = getreg('/')
   " After *                i^r/ will give me pattern instead of \<pattern\>
   let res = substitute(reg, '^\\<\(.*\)\\>$', '\1', '' )
   if res != reg
      return res
   endif
   " After * on a selection i^r/ will give me pattern instead of \Vpattern
   let res = substitute(reg, '^\\V'          , ''  , '' )
   let res = substitute(res, '\\\\'          , '\\', 'g')
   let res = substitute(res, '\\n'           , '\n', 'g')
   return res
endfunction
inoremap <silent> <c-r>/ <c-r>=Del_word_delims()<cr>
cnoremap          <c-r>/ <c-r>=Del_word_delims()<cr>

For more complicated patterns, it's better to act on the text matched with the last search, using the gn object.

So, you could also accomplish insertion of a search match using maygn`ap in normal mode. I.e. ma to drop a mark to return to later, y to yank the gn object, then `a to jump back where you were (because the yank will leave you on the text copied), finally p to paste.

When starting from insert mode, you don't even need a mark: you can use the gi command to start again from where you left off. For example:

:inoremap <F3> <Esc>ygngi<C-R>0

Here, ygn is as before, but gi is used to go back to insert mode in the same place you left off, then <C-R>0 inserts the copied text.

See alsoEdit

CommentsEdit

 TO DO 
Tips related to visual searching (need to merge):

This mapping forms a substitute command with the selected text:

vnoremap <C-r> "hy:%s/<C-r>h//gc<left><left><left>

Found on Stack Overflow: Vim replace selected text.

To auto escape certain characters (e.g. slash and backslash), one can use:

vnoremap <C-h> ""y:%s/<C-R>=escape(@", '/\')<CR>//g<Left><Left>

Around Wikia's network

Random Wiki