Vim Tips Wiki
Register
(Adjust previous/next navigation)
(Add a simple, one-liner solution to the problem, to accommodate anyone looking for a hassle-free snippet.)
Tag: Visual edit
(8 intermediate revisions by 7 users not shown)
Line 12: Line 12:
 
}}
 
}}
 
With this tip, you can select some text, then press a key to search for the next occurrence of the text. Two alternative methods are presented.
 
With this tip, you can select some text, then press a key to search for the next occurrence of the text. Two alternative methods are presented.
  +
  +
== '''Simple''' ==
  +
The simplest solution is:
  +
vnorem // y/<c-r>"<cr>
  +
  +
== Advanced ==
  +
The following is a more advanced implementation, with more robust functionality than the above keymap.
   
 
'''Features'''
 
'''Features'''
*Press <tt>*</tt> to search forwards for selected text, or <tt>#</tt> to search backwards.
+
*Press <code>*</code> to search forwards for selected text, or <code>#</code> to search backwards.
*As normal, press <tt>n</tt> for next search, or <tt>N</tt> for previous.
+
*As normal, press <code>n</code> for next search, or <code>N</code> for previous.
 
*Handles multiline selection and search.
 
*Handles multiline selection and search.
 
*Whitespace in the selection matches ''any'' whitespace when searching (searching for "hello world" will also find "hello" at the end of a line, with "world" at the start of the next line).
 
*Whitespace in the selection matches ''any'' whitespace when searching (searching for "hello world" will also find "hello" at the end of a line, with "world" at the start of the next line).
Line 37: Line 44:
   
 
Following is an alternative version with some extra features:
 
Following is an alternative version with some extra features:
*A global variable (<tt>g:VeryLiteral</tt>) controls whether selected whitespace matches any whitespace (by default, VeryLiteral is off, so any whitespace is found).
+
*A global variable (<code>g:VeryLiteral</code>) controls whether selected whitespace matches any whitespace (by default, VeryLiteral is off, so any whitespace is found).
*Type <tt>\vl</tt> to toggle VeryLiteral to turn whitespace matching off/on (assuming the default backslash leader key).
+
*Type <code>\vl</code> to toggle VeryLiteral to turn whitespace matching off/on (assuming the default backslash leader key).
 
*When VeryLiteral is off, any selected leading or trailing whitespace will not match newlines, which is more convenient, and avoids false search hits.
 
*When VeryLiteral is off, any selected leading or trailing whitespace will not match newlines, which is more convenient, and avoids false search hits.
   
Create file (for example) <tt>~/.vim/plugin/vsearch.vim</tt> (Unix) or <tt>$HOME/vimfiles/plugin/vsearch.vim</tt> (Windows) with contents:
+
Create file (for example) <code>~/.vim/plugin/vsearch.vim</code> (Unix) or <code>$HOME/vimfiles/plugin/vsearch.vim</code> (Windows) with contents:
 
<pre>
 
<pre>
 
" Search for selected text.
 
" Search for selected text.
Line 49: Line 56:
 
let g:VeryLiteral = 0
 
let g:VeryLiteral = 0
 
endif
 
endif
 
 
function! s:VSetSearch(cmd)
 
function! s:VSetSearch(cmd)
 
let old_reg = getreg('"')
 
let old_reg = getreg('"')
Line 70: Line 76:
 
call setreg('"', old_reg, old_regtype)
 
call setreg('"', old_reg, old_regtype)
 
endfunction
 
endfunction
 
 
vnoremap <silent> * :<C-U>call <SID>VSetSearch('/')<CR>/<C-R>/<CR>
 
vnoremap <silent> * :<C-U>call <SID>VSetSearch('/')<CR>/<C-R>/<CR>
 
vnoremap <silent> # :<C-U>call <SID>VSetSearch('?')<CR>?<C-R>/<CR>
 
vnoremap <silent> # :<C-U>call <SID>VSetSearch('?')<CR>?<C-R>/<CR>
 
vmap <kMultiply> *
 
vmap <kMultiply> *
 
 
nmap <silent> <Plug>VLToggle :let g:VeryLiteral = !g:VeryLiteral
 
nmap <silent> <Plug>VLToggle :let g:VeryLiteral = !g:VeryLiteral
 
\\| echo "VeryLiteral " . (g:VeryLiteral ? "On" : "Off")<CR>
 
\\| echo "VeryLiteral " . (g:VeryLiteral ? "On" : "Off")<CR>
Line 93: Line 97:
 
</pre>
 
</pre>
   
When in visual mode, pressing <tt>*</tt> will then perform these commands:
+
When in visual mode, pressing <code>*</code> will then perform these commands:
 
<pre>
 
<pre>
 
:<C-U>
 
:<C-U>
Line 108: Line 112:
 
</pre>
 
</pre>
   
<tt>:<C-U></tt> enters command mode and deletes (Ctrl-u) the <tt>'<,'></tt> range automatically inserted due to the visual selection. The unnamed register (<tt>@"</tt>) is saved and later restored.
+
<code>:<C-U></code> enters command mode and deletes (Ctrl-u) the <code>'<,'></code> range automatically inserted due to the visual selection. The unnamed register (<code>@"</code>) is saved and later restored.
   
<tt>gvy</tt> reselects then yanks the visual selection (copy to <tt>@"</tt>).
+
<code>gvy</code> reselects then yanks the visual selection (copy to <code>@"</code>).
   
<tt>/<C-R><C-R>=</tt> starts a search, then substitutes the expression register (<tt>@=</tt>) literally {{help|c_CTRL-R_CTRL-R}}. The result of the following expression is inserted into the command line.
+
<code>/<C-R><C-R>=</code> starts a search, then substitutes the expression register (<code>@=</code>) literally {{help|c_CTRL-R_CTRL-R}}. The result of the following expression is inserted into the command line.
   
<tt>escape()</tt> inserts a backslash before each <tt>/\.*$^~[</tt> character found in <tt>@"</tt>. The <tt>/</tt> must be escaped because we are using a <tt>/</tt> command. The other characters need to be escaped because they have a special meaning in a regular expression.
+
<code>escape()</code> inserts a backslash before each <code>/\.*$^~[</code> character found in <code>@"</code>. The <code>/</code> must be escaped because we are using a <code>/</code> command. The other characters need to be escaped because they have a special meaning in a regular expression.
   
<tt>substitute()</tt> replaces every sequence of one or more whitespace characters (space, tab, newline) with an escaped regular expression that will search for any similar sequence.
+
<code>substitute()</code> replaces every sequence of one or more whitespace characters (space, tab, newline) with an escaped regular expression that will search for any similar sequence.
   
<tt>gV</tt> allows the mappings to work in <tt>--SELECT--</tt> mode as well as <tt>--VISUAL--</tt>. Without <tt>gV</tt>, searching for text in select mode would not move the cursor because the selection is automatically reselected after the mapping.
+
<code>gV</code> allows the mappings to work in <code>--SELECT--</code> mode as well as <code>--VISUAL--</code>. Without <code>gV</code>, searching for text in select mode would not move the cursor because the selection is automatically reselected after the mapping.
  +
  +
  +
==Paste matching text of last search==
  +
When using <code>^r/</code> in INSERT mode what one most of the time wants is to paste the matched text not the regex used to search the text. Example: after using * on a word, <code>^r/</code> will paste the word with <code>\<</code> prepended and <code>\></code> appended, not what we want. Similarly after a visual search we don't want the <code>\V</code> prepended. The following map takes care of these issues:
  +
<source lang="vim">
  +
function! Del_word_delims()
  +
let reg = getreg('/')
  +
" After * i^r/ will give me pattern instead of \<pattern\>
  +
let res = substitute(reg, '^\\<\(.*\)\\>$', '\1', '' )
  +
if res != reg
  +
return res
  +
endif
  +
" After * on a selection i^r/ will give me pattern instead of \Vpattern
  +
let res = substitute(reg, '^\\V' , '' , '' )
  +
let res = substitute(res, '\\\\' , '\\', 'g')
  +
let res = substitute(res, '\\n' , '\n', 'g')
  +
return res
  +
endfunction
  +
inoremap <silent> <c-r>/ <c-r>=Del_word_delims()<cr>
  +
cnoremap <c-r>/ <c-r>=Del_word_delims()<cr>
  +
</source>
  +
  +
For more complicated patterns, it's better to act on the text matched with the last search, using the {{help|prefix=no|gn}} object.
  +
  +
So, you could also accomplish insertion of a search match using <code>maygn`ap</code> in normal mode. I.e. <code>ma</code> to drop a mark to return to later, <code>y</code> to yank the <code>gn</code> object, then <code>`a</code> to jump back where you were (because the yank will leave you on the text copied), finally <code>p</code> to paste.
  +
  +
When starting from insert mode, you don't even need a mark: you can use the <code>gi</code> command to start again from where you left off. For example:
  +
  +
<pre>
  +
:inoremap <F3> <Esc>ygngi<C-R>0
  +
</pre>
  +
  +
Here, <code>ygn</code> is as before, but <code>gi</code> is used to go back to insert mode in the same place you left off, then <code><C-R>0</code> inserts the copied text.
  +
  +
==See also==
  +
* [[Script:2944|visualstar.vim]]
   
 
==Comments==
 
==Comments==
Line 126: Line 166:
 
*[[VimTip1151|1151 Search visually]]
 
*[[VimTip1151|1151 Search visually]]
   
  +
This mapping forms a substitute command with the selected text:
----
 
  +
<pre>
  +
vnoremap <C-r> "hy:%s/<C-r>h//gc<left><left><left>
  +
</pre>
  +
Found on [http://stackoverflow.com/questions/676600/vim-replace-selected-text Stack Overflow: Vim replace selected text].
  +
  +
To auto escape certain characters (e.g. slash and backslash), one can use:
  +
<pre>
  +
vnoremap <C-h> ""y:%s/<C-R>=escape(@", '/\')<CR>//g<Left><Left>
  +
</pre>

Revision as of 20:02, 6 June 2014

Tip 171 Printable Monobook Previous Next

created 2001 · complexity basic · author Raymond Li · version 6.0


With this tip, you can select some text, then press a key to search for the next occurrence of the text. Two alternative methods are presented.

Simple

The simplest solution is:

vnorem // y/<c-r>"<cr>

Advanced

The following is a more advanced implementation, with more robust functionality than the above keymap.

Features

  • Press * to search forwards for selected text, or # to search backwards.
  • As normal, press n for next search, or N for previous.
  • Handles multiline selection and search.
  • Whitespace in the selection matches any whitespace when searching (searching for "hello world" will also find "hello" at the end of a line, with "world" at the start of the next line).
  • Each search is placed in the search history allowing you to easily repeat previous searches.
  • No registers are changed.

Place the following mappings in your vimrc:

" Search for selected text, forwards or backwards.
vnoremap <silent> * :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy/<C-R><C-R>=substitute(
  \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>
vnoremap <silent> # :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy?<C-R><C-R>=substitute(
  \escape(@", '?\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>

Following is an alternative version with some extra features:

  • A global variable (g:VeryLiteral) controls whether selected whitespace matches any whitespace (by default, VeryLiteral is off, so any whitespace is found).
  • Type \vl to toggle VeryLiteral to turn whitespace matching off/on (assuming the default backslash leader key).
  • When VeryLiteral is off, any selected leading or trailing whitespace will not match newlines, which is more convenient, and avoids false search hits.

Create file (for example) ~/.vim/plugin/vsearch.vim (Unix) or $HOME/vimfiles/plugin/vsearch.vim (Windows) with contents:

" Search for selected text.
" http://vim.wikia.com/wiki/VimTip171
let s:save_cpo = &cpo | set cpo&vim
if !exists('g:VeryLiteral')
  let g:VeryLiteral = 0
endif
function! s:VSetSearch(cmd)
  let old_reg = getreg('"')
  let old_regtype = getregtype('"')
  normal! gvy
  if @@ =~? '^[0-9a-z,_]*$' || @@ =~? '^[0-9a-z ,_]*$' && g:VeryLiteral
    let @/ = @@
  else
    let pat = escape(@@, a:cmd.'\')
    if g:VeryLiteral
      let pat = substitute(pat, '\n', '\\n', 'g')
    else
      let pat = substitute(pat, '^\_s\+', '\\s\\+', '')
      let pat = substitute(pat, '\_s\+$', '\\s\\*', '')
      let pat = substitute(pat, '\_s\+', '\\_s\\+', 'g')
    endif
    let @/ = '\V'.pat
  endif
  normal! gV
  call setreg('"', old_reg, old_regtype)
endfunction
vnoremap <silent> * :<C-U>call <SID>VSetSearch('/')<CR>/<C-R>/<CR>
vnoremap <silent> # :<C-U>call <SID>VSetSearch('?')<CR>?<C-R>/<CR>
vmap <kMultiply> *
nmap <silent> <Plug>VLToggle :let g:VeryLiteral = !g:VeryLiteral
  \\| echo "VeryLiteral " . (g:VeryLiteral ? "On" : "Off")<CR>
if !hasmapto("<Plug>VLToggle")
  nmap <unique> <Leader>vl <Plug>VLToggle
endif
let &cpo = s:save_cpo | unlet s:save_cpo

Explanation

The first suggested mapping was:

vnoremap <silent> * :<C-U>
  \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
  \gvy/<C-R><C-R>=substitute(
  \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR>
  \gV:call setreg('"', old_reg, old_regtype)<CR>

When in visual mode, pressing * will then perform these commands:

:<C-U>
let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR>
gvy
/<C-R><C-R>=
substitute(
  escape(@", '/\.*$^~['),
  '\_s\+',
  '\\_s\\+',
  'g')<CR><CR>
gV
:call setreg('"', old_reg, old_regtype)<CR>

:<C-U> enters command mode and deletes (Ctrl-u) the '<,'> range automatically inserted due to the visual selection. The unnamed register (@") is saved and later restored.

gvy reselects then yanks the visual selection (copy to @").

/<C-R><C-R>= starts a search, then substitutes the expression register (@=) literally :help c_CTRL-R_CTRL-R. The result of the following expression is inserted into the command line.

escape() inserts a backslash before each /\.*$^~[ character found in @". The / must be escaped because we are using a / command. The other characters need to be escaped because they have a special meaning in a regular expression.

substitute() replaces every sequence of one or more whitespace characters (space, tab, newline) with an escaped regular expression that will search for any similar sequence.

gV allows the mappings to work in --SELECT-- mode as well as --VISUAL--. Without gV, searching for text in select mode would not move the cursor because the selection is automatically reselected after the mapping.


Paste matching text of last search

When using ^r/ in INSERT mode what one most of the time wants is to paste the matched text not the regex used to search the text. Example: after using * on a word, ^r/ will paste the word with \< prepended and \> appended, not what we want. Similarly after a visual search we don't want the \V prepended. The following map takes care of these issues:

function! Del_word_delims()
   let reg = getreg('/')
   " After *                i^r/ will give me pattern instead of \<pattern\>
   let res = substitute(reg, '^\\<\(.*\)\\>$', '\1', '' )
   if res != reg
      return res
   endif
   " After * on a selection i^r/ will give me pattern instead of \Vpattern
   let res = substitute(reg, '^\\V'          , ''  , '' )
   let res = substitute(res, '\\\\'          , '\\', 'g')
   let res = substitute(res, '\\n'           , '\n', 'g')
   return res
endfunction
inoremap <silent> <c-r>/ <c-r>=Del_word_delims()<cr>
cnoremap          <c-r>/ <c-r>=Del_word_delims()<cr>

For more complicated patterns, it's better to act on the text matched with the last search, using the gn object.

So, you could also accomplish insertion of a search match using maygn`ap in normal mode. I.e. ma to drop a mark to return to later, y to yank the gn object, then `a to jump back where you were (because the yank will leave you on the text copied), finally p to paste.

When starting from insert mode, you don't even need a mark: you can use the gi command to start again from where you left off. For example:

:inoremap <F3> <Esc>ygngi<C-R>0

Here, ygn is as before, but gi is used to go back to insert mode in the same place you left off, then <C-R>0 inserts the copied text.

See also

Comments

 TO DO 
Tips related to visual searching (need to merge):

This mapping forms a substitute command with the selected text:

vnoremap <C-r> "hy:%s/<C-r>h//gc<left><left><left>

Found on Stack Overflow: Vim replace selected text.

To auto escape certain characters (e.g. slash and backslash), one can use:

vnoremap <C-h> ""y:%s/<C-R>=escape(@", '/\')<CR>//g<Left><Left>