Automatically append closing characters
From Vim Tips Wiki
Tip 630 Previous Next created January 2, 2004 · complexity basic · author Andrzej Cuber · version 6.0
Contents |
[edit] A simple solution
When you type an open brace, this will automatically insert a closing brace on the same line, after the cursor. If you quickly hit Enter after the open brace, (to begin a code block), the closing brace will be inserted on the line below the cursor. If you quickly press the open brace key again after the open brace, Vim won't insert anything extra, you'll just get a single open brace. Finally, if you quickly type an open and close brace, Vim will not do anything special.
inoremap { {}<Left>
inoremap {<CR> {<CR>}<Esc>O
inoremap {{ {
inoremap {} {}
One thing to be aware of with these mappings is that they will interrupt your undo sequence, as documented at :help ins-special-special. This means that after using these mappings and inserting more text between the braces, pressing 'u' will only undo the text inserted between the braces. Pressing '.' will similarly only insert the same text.
[edit] Skipping over the closing brace
Similar mappings for other "paired" characters can be made from the above with trivial modifications, but characters like brackets and parentheses which often require text after them might instead benefit from something like the following, which automatically closes all groups, and skips over existing closing characters if another one is typed immediately before:
inoremap ( ()<Left>
inoremap <expr> ) strpart(getline('.'), col('.')-1, 1) == ")" ? "\<Right>" : ")"
This solution works by looking at the character just after the cursor (which confusingly enough is at the cursor column - 1), and simply moving the cursor if it is the closing character. If the character after the cursor is not the closing character, it will insert the closing character. The mapping fairly straightforward, but unfortunately will not work prior to Vim 7.0 which introduced <expr> mappings. You'll need to modify this slightly for older versions of Vim.
[edit] Managing paired character sequences
For adding multiple-character pairs such as C-style comments, you may want to find another way to prevent the mapping from taking effect, such as typing the mapleader (usually '\' – see :help mapleader) character first as below:
inoremap /* /**/<Left><Left> inoremap /*<Space> /*<Space><Space>*/<Left><Left><Left> inoremap /*<CR> /*<CR>*/<Esc>O inoremap <Leader>/* /*
Similar mappings might be useful for quotes, but they might get in your way depending on the type of file you're editing. Some languages use duplicate single-quotes a lot, and some pair the backtick with the quote. For these situations, you might want to put similar commands into language-specific files. For example, this quote-completer for GNU M4 might live in ~/.vim/after/ftplugin/m4.vim. :help after-directory
inoremap ` `')<Left><Left> inoremap `<CR> `<CR>'<Esc>O inoremap `` ` inoremap `' `'
[edit] More advanced solutions
If you want something more complex and configurable, there are a number of different scripts that accomplish this task.
[edit] Plugins
The pure auto-insertion of matching brackets is provided by these plugins:
Luc Hermitte has some very advanced and smart ftplugins for editing C & C++ files . Those scripts give advanced brace-handling features like markers support (placeholders in another terminology), several things can be easily tweaked (whether we want newlines or not before the curly-brackets, ...), the abbreviations are buffer-relative (which is necessary to have "for" expand into different things according to the filetype of the buffer edited), context-sensitive (the abbreviations are not expanded within comments or string contexts) and more.
See also the core bracketing system and the C&C++ ftplugin suite built on top of it.
Srinath Avadhanula's imaps.vim is used by Latex-Suite to provide a similar bracketing system.
[edit] ReplaceCurly script
This script operates only on braces, but is smarter about detecting when it should act. It will not take effect when editing comments, strings and lines containing the the word "new." (This is useful for array initialization, e.g. string[] myArray = new string[] {"a", "b"}.)
imap { <Esc>:call ReplaceCurly()<CR>"_cl
function! ReplaceCurly()
imap { {
" only replace outside of comments or strings (which map to constant)
let elesyn = synIDtrans(synID(line("."), col(".") - 1, 0))
if elesyn != hlID('Comment') && elesyn != hlID('Constant') && match(getline("."), "\\<new\\>") < 0
exe "normal a{"
" need to add a spare character (x) to position the cursor afterwards
exe "normal ox"
exe "normal o}"
exe "normal kw"
else
" need to add a spare character (x) to position the cursor afterwards
exe "normal a{x"
endif
imap { <Esc>:let word= ReplaceCurly()<CR>"_cl
endfunction
"Surround code with braces
nmap <Leader>{} O{<Esc>ddj>>ddkP
vmap <Leader>{} <Esc>o{<Esc>ddgv>gvdp
[edit] Backwards-compatible closing brace skip
If you need a solution for inserting a closing brace automatically in a pre-7.0 Vim, you can slightly modify the <expr> mapping given above to use the expression register instead:
inoremap ) <C-R>=strpart(getline('.'), col('.')-1, 1) == ")" ? "\<lt>Right>" : ")"<CR>
Note that we needed to treat the "\<Right>" text differently so that it is expanded when expression register is evaluated instead of when the mapping is executed.
